How to delete all ssid's and passwords saved?

[DanielSamp4]

Hello, Frist congratulations from an escellent work. I've been needing to remove all the ssid's saved from ESP32 or just a way to get all ssid saved. i dont want to erase all the flash memory just to be able to reset the wifi credential.

Thank all to help.

[Bighoneypot]

Hi @DanielSamp4 , on Arduino Ide, select erase flase, and select Only sketch

[guedesopaulo]

But it is possible to do what @DanielSamp4 want by code?

[DanielSamp4]

Thanks for your reply @Bighoneypot,
i think I expressed myself badly, i mean a way of doing this not mannually.

[Hieromon]

@DanielSamp4
What you need may be here.
The sketch that drives the service function described there is:

#include <WiFi.h>
#include <WiFiServer.h>
#include <AutoConnect.h>

void deleteAllCredentials(void) {
  AutoConnectCredential credential;
  station_config_t config;
  uint8_t ent = credential.entries();

  Serial.println("AutoConnectCredential deleting");
  if (ent)
    Serial.printf("Available %d entries.\n", ent);
  else {
    Serial.println("No credentials saved.");
    return;
  }

  while (ent--) {
    credential.load((int8_t)0, &config);
    if (credential.del((const char*)&config.ssid[0]))
      Serial.printf("%s deleted.\n", (const char*)config.ssid);
    else
      Serial.printf("%s failed to delete.\n", (const char*)config.ssid);
  }
}

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println();
  deleteAllCredentials();
}

void loop() {
}

If you receive an error as [E] [Preferences.cpp: 50] begin(): nvs_open failed: NOT_FOUND message, you don't have to worry about it. AutoConnect uses NVS to store credentials, and NVS is automatically created when AutoConnect saves credentials for the first time.

[DanielSamp4]

Thank you so much, this function worked very well :DD

[JosuaK03]

@Hieromon, thanks also for your great work!

I was also able to delete my stored credentials this way.
However, I have encountered the following problem:
I can delete my credentials, but my ESP still automatically connects to the last deleted AP after a reset.

Do you know how I can put it back into captive-portal-mode to connect it to another AP (via code)?

My code:

#include <WiFi.h>
#include <WebServer.h>
#include <AutoConnect.h>
#include <AutoConnectCredential.h>

const int WifiReset = 25; //Touch-Pin

WebServer server;
AutoConnect Portal(server);
AutoConnectConfig Config(ssid, password);

void deleteAllCredentials(void) {
  AutoConnectCredential credential;
  station_config_t config;
  uint8_t ent = credential.entries();

  Serial.println("AutoConnectCredential deleting");
  if (ent)
    Serial.printf("Available %d entries.\n", ent);
  else {
    Serial.println("No credentials saved.");
    return;
  }

  while (ent--) {
    credential.load((int8_t)0, &config);
    if (credential.del((const char*)&config.ssid[0]))
      Serial.printf("%s deleted.\n", (const char*)config.ssid);
    else
      Serial.printf("%s failed to delete.\n", (const char*)config.ssid);
  }
}

void Reset(){
    Serial.println("--------------------------");
    Serial.println("ESP reseting...");    
    deleteAllCredentials();
    WiFi.disconnect(true);
    if (!WiFi.isConnected())
      Serial.println("WiFi disconnected");
    Serial.println("rebooting...");
    Serial.println("--------------------------");
    ESP.restart();
}

void ResetLookUp(){
  if(digitalRead(WifiReset) == HIGH)
    Reset();
}

void setup() {
  pinMode(WifiReset, INPUT);
  
  Serial.begin(115200);
  Serial.println();

  LaunchPortal();
}

void LaunchPortal() {
  Config.apid = ssid;
  Config.apip = IPAddress(192,168,10,10);       // Sets SoftAP IP address
  Config.gateway = IPAddress(192,168,10,1);     // Sets WLAN router IP address
  Config.netmask = IPAddress(255,255,255,0);    // Sets Netmask
  Config.autoReconnect = true;                  // Enable auto-reconnect
  Config.autoReset = false;
  Config.autoSave = AC_SAVECREDENTIAL_AUTO;     // save credential
  Config.autoRise = true;
  Config.title ="ESP32";
  Config.menuItems = AC_MENUITEM_CONFIGNEW;
  Portal.config(Config);

  Portal.onConnect([](IPAddress& ipaddr){
    if (WiFi.getMode() & WIFI_AP){
      WiFi.softAPdisconnect(true);
      WiFi.enableAP(false);
      Serial.printf("SoftAP:%s shut down\n", WiFi.softAPSSID().c_str());
    }
  });

  if (Portal.begin()) {
    Serial.println("Connected with " + WiFi.SSID() + " IP: " + WiFi.localIP().toString());
    Serial.println("MAC-Adress: " + WiFi.macAddress());
  }
  else {
    Serial.println("Connection failed.");
    while(true) { ESP.restart(); }
  }
}

void loop() {
  server.handleClient();
  Portal.handleRequest();
  ResetLookUp();
}

Best regards!

[Hieromon]

Maybe you haven't cleared the AP configuration that the ESP32 core memorizes. Your sketch performs a WiFi disconnect in the Reset function, but the WiFiSTAClass::disconnect function has a second parameter that specifies clearing the memorized AP configuration of the ESP32 core. Its default value is false.
https://github.com/espressif/arduino-esp32/blob/46d5afb17fb91965632dc5fef237117e1fe947fc/libraries/WiFi/src/WiFiSTA.h#L46

If its second parameter is false, the ESP32 core WiFi library will not erase the memorized configuration data. (If the second parameter is true, the memorized configuration will be zero cleared by esp_wifi_set_config)
https://github.com/espressif/arduino-esp32/blob/46d5afb17fb91965632dc5fef237117e1fe947fc/libraries/WiFi/src/WiFiSTA.cpp#L247-L269

Then, its configuration will be reused by esp_wifi_get_config in WiFi.begin which has no parameters. (it's AutoConnect's 1st-WiFI.begin)
https://github.com/espressif/arduino-esp32/blob/46d5afb17fb91965632dc5fef237117e1fe947fc/libraries/WiFi/src/WiFiSTA.cpp#L205-L206

Could you try the following changes with WiFi.disconnect in the Reset function?

  Serial.println("ESP reseting...");    
  deleteAllCredentials();
  WiFi.disconnect(true, true); // Clear memorized STA configuration
  if (!WiFi.isConnected())
    Serial.println("WiFi disconnected");

[faanskit]

If WiFi.disconnect(true, true) is run before Portal.begin() it will will fail.
In a factory reset type function, which occurs early in the setup()/boot, one can add WiFi.begin() beforeWiFi.disconnect(true, true).
I.e.

  // First, connect to any saved WiFi. Else WiFi.disconnect() operation will fail
  WiFi.begin();

  // Clear memorized STA configuration
  if(!WiFi.disconnect(true, true)){ 
    log_e("WiFi disconnect failed");
  }

[JosuaK03]

Thanks for the quick reply, that worked :D