build.gradle

plugins {
  id 'java'
    id 'org.springframework.boot' version '3.2.4'
    id 'io.spring.dependency-management' version '1.1.4'
    id "org.asciidoctor.jvm.convert" version "3.3.2"
    id 'com.github.andygoossens.modernizer' version '1.9.0'
    id 'com.github.spotbugs' version '6.0.8'
    id 'jacoco'
}

group = 'mirante.api'
version = '0.3.0-SNAPSHOT'
def spring_version = '6.1.5'
def spring_security_version = '6.2.3'
def spring_docs_version = '3.0.1'

java {
  sourceCompatibility = JavaVersion.VERSION_17
}

repositories {
  mavenCentral()
}

configurations {
  umlDoclet
  asciidoctorExt
}

dependencies {
  implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
  implementation 'org.springframework.boot:spring-boot-starter-data-rest'
  implementation 'org.springframework.boot:spring-boot-starter-security'
  implementation 'org.springframework.boot:spring-boot-starter-webflux'
  implementation 'jakarta.inject:jakarta.inject-api:2.0.1'
  implementation "org.springframework.security:spring-security-crypto:${spring_security_version}"
  implementation 'org.bouncycastle:bcprov-jdk15on:1.69'
  implementation 'commons-io:commons-io:2.15.1'
  implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.2.0'
  implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
  implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'
  testImplementation 'org.springframework.boot:spring-boot-starter-test'
  testImplementation 'org.springframework.boot:spring-boot-starter-web'
  testImplementation 'org.springframework.boot:spring-boot-starter-security'
  testImplementation 'org.springframework.security:spring-security-test'
  testImplementation "org.springframework.restdocs:spring-restdocs-webtestclient:${spring_docs_version}"
  testImplementation 'de.elnarion.util:plantuml-generator-util:2.4.1'
  testImplementation group: 'com.credibledoc', name: 'plantuml-core', version: '1.0.51'
  runtimeOnly 'com.h2database:h2'
  runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
  umlDoclet "nl.talsmasoftware:umldoclet:2.1.1"
  asciidoctorExt "org.springframework.restdocs:spring-restdocs-asciidoctor:${spring_docs_version}"
}

tasks.register('copyDocs', Copy) {
  dependsOn jacocoTestReport, javadoc, asciidoctor
  from layout.buildDirectory.dir("reports")
  from layout.buildDirectory.dir("docs")
  from layout.buildDirectory.dir("generated-snippets")
  from layout.buildDirectory.dir("asciidoc")
  into layout.projectDirectory.dir("docs/generated")
}

tasks.register('generatePlantUML') {
  test {
    systemProperty "fullBuild", new String("true")
    filter {
      includeTestsMatching('PlantUMLGeneratorTest')
    }
  }
}

def snippetsDir = file('build/generated-snippets')

test {
  outputs.dir snippetsDir
  useJUnitPlatform()
}

javadoc {
  source = sourceSets.main.allJava
  options.docletpath = configurations.umlDoclet.files as List
  options.doclet = "nl.talsmasoftware.umldoclet.UMLDoclet"
}

asciidoctor {
  inputs.dir snippetsDir
  configurations 'asciidoctorExt'
  dependsOn test
}

modernizer {
  failOnViolations = true
}

spotbugs {
  ignoreFailures = true
}

jacocoTestReport {
  reports {
    xml.required = true
    csv.required = true
  }
}

jacocoTestCoverageVerification {
  violationRules {
    rule {
      limit {
        // minimum = 0.20
      }
    }
  }
}

tasks.register('fullBuild', GradleBuild) {
  tasks = [
          'jacocoTestCoverageVerification',
          'jacocoTestReport',
          'build',
          'javadoc',
          'asciidoctor',
          'generatePlantUML',
          'copyDocs'
  ]
}