thread.when delay

[gAlleb]

How can we delay the execution of a function on predicate?

E.g. When brbr = true - I want to skip a source but with a delay.

thread.when(predicate.activates({brbr()}), fun() -> radio.skip())

thread.when(predicate.activates({brbr()}), fun() -> thread.run(my_function, delay=10., fast=false)) doesn't work, of course.

def thread.when
  ~fast=true,
  ~init=true,
  ~every=getter(0.5),
  ~once=false,
  ~changed=true,
  ~on_error=null(),
  p,
  f
) =
  p = once or not changed ? p : (predicate.activates(init=init, p))

  def check() =
    if
      p()
    then
      f()
      once ? (-1.) : (getter.get(every))
    else
      getter.get(every)
    end
  end

  thread.run.recurrent(fast=fast, delay=0., on_error=on_error, check)
end

[vitoyucepi]

Hi @gAlleb,

p = ref(false)

thread.when(
  predicate.activates(p),
  fun() -> begin
    print("On activate #{time.up()}")
    thread.run({print("Delayed #{time.up()}")}, delay=10., fast=false)
  end
)

print("Start #{time.up()}")
thread.run(
  fun() -> begin
    print("Activate #{time.up()}")
    p := true
  end,
  delay=10.
)

Start 0.590755939484
Activate 10.5919101238
On activate 10.6112821102
Delayed 20.6115019321

[gAlleb]

Thanks @vitoyucepi. So begin end block solves it. I've had it in one of my attempts but probably wasn't attentive! thank you!

[vitoyucepi]

The begin and end statements here are just for readability, everything should work without them if you write everything correctly, e.g. using (anonymous) functions.

{} functions

p = ref(false)

thread.when(
  predicate.activates(p),
  {
    print("On activate #{time.up()}")
    thread.run({print("Delayed #{time.up()}")}, delay=10., fast=false)
  }
)

print("Start #{time.up()}")
thread.run(
  {
    print("Activate #{time.up()}")
    p := true
  },
  delay=10.
)

p = ref(false)

thread.when(predicate.activates(p), {print("On activate #{time.up()}"); thread.run({print("Delayed #{time.up()}")}, delay=10., fast=false)})

print("Start #{time.up()}")
thread.run({print("Activate #{time.up()}"); p := true}, delay=10.)

Named functions

p = ref(false)

def delayed()
  print("Delayed #{time.up()}")
end

def on_activate()
  print("On activate #{time.up()}")
  thread.run(delayed, delay=10., fast=false)
end

thread.when(predicate.activates(p), on_activate)

print("Start #{time.up()}")

def activate()
  print("Activate #{time.up()}")
  p := true
end

thread.run(activate, delay=10.)

[gAlleb]

hm, magical) Well, it's always something wrong with me)

Thank you!