-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathswtbug11.asm
725 lines (657 loc) · 24.9 KB
/
swtbug11.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
;*******************************************************************************
; SWTBUG VERSION 1.00 - REPLACEMENT FOR MIKBUG ROM
; FOR SWTPC 6800 COMPUTER SYSTEM
; COPYRIGHT 1977
; SOUTHWEST TECHNICAL PROD. CORP.
; AUGUST, 1977
;*******************************************************************************
;
; Revised for the 68HC11
; 15 December 2002
; John E. Kent
#RAM $A000
IRQ rmb 2 ; IRQ POINTER
BEGA rmb 2 ; BEGINNING ADDR PNCH
ENDA rmb 2 ; ENDING ADDR PNCH
NMI rmb 2 ; NMI INTERRUPT VECTOR
SP rmb 1 ; S HIGH
rmb 1 ; S LOW
PORADD rmb 2 ; PORT ADDRESS
PORECH rmb 1 ; ECHO ON/OFF FLAG
XHI rmb 1 ; XREG HIGH
XLOW rmb 1 ; XREG LOW
CKSM rmb 1 ; CHECKSUM
XTEMP rmb 2 ; X-REG TEMP STGE
SWIJMP rmb 2 ; SWI JUMP VECTOR
TW equ $A044 ; TEMPORARY STORAGE
TEMP equ $A046 ; TEMPORARY STORAGE
BYTECT equ $A047 ; BYTECT AND MCONT TEMP.
CTLPOR equ $8004 ; CONTROL PORT ADDRESS
PROM equ $C000 ; JUMP TO PROM ADDRESS
BKPT rmb 2 ; BREAKPOINT ADDRESS
BKLST rmb 1 ; BREAKPOINT DATA
;
; Two more bytes added to the stack
; for the IY register
;
STACK equ $A040 ; SWTBUG STACK
#ROM $E000
;
; I/O INTERRUPT SEQUENCE
IRQV ldx IRQ
jmp 0,x
;
; JUMP TO USER PROGRAM
JUMP bsr BADDR
jmp 0,x
;
CURSOR fcb $10,$16,4 ; CT-1024 CURSOR CONTROL
;
; ASCII LOADING ROUTINE
LOAD jsr RDON ; READER ON, DIS ECHO, GET P#
LOAD3 bsr INCH
cmpa #'S'
bne LOAD3 ; 1ST CHAR NOT S
bsr INCH ; READ CHAR
cmpa #'9'
beq LOAD21
cmpa #'1'
bne LOAD3 ; 2ND CHAR NOT 1
clr CKSM ; ZERO CHECKSUM
bsr BYTE ; READ BYTE
suba #2
sta BYTECT ; BYTE COUNT
; BUILD ADDRESS
bsr BADDR
; STORE DATA
LOAD11 bsr BYTE
dec BYTECT
beq LOAD15 ; ZERO BYTE COUNT
sta 0,x ; STORE DATA
cmpa 0,x ; DATA STORED?
bne LOAD19
inx
bra LOAD11
LOAD15 inc CKSM
beq LOAD3
LOAD19 lda #'?'
bsr OUTCH
LOAD21 jmp RDOFF1
;
; BUILD ADDRESS
BADDR bsr BYTE ; READ 2 FRAMES
sta XHI
bsr BYTE
sta XLOW
ldx XHI ; LOAD IXR WITH NUMBER
rts
;
; INPUT BYTE (TWO FRAMES)
BYTE bsr INHEX ; GET HEX CHAR
BYTE1 asla
asla
asla
asla
tab
bsr INHEX
aba
tab
addb CKSM
stb CKSM
rts
;
OUTHL lsra ; OUT HEX LEFT BCD DIGIT
lsra
lsra
lsra
OUTHR anda #$F ; OUT HEX RIGHT BCD DIGIT
adda #$30
cmpa #$39
bls OUTCH
adda #$7
;
; OUTPUT ONE CHAR
OUTCH jmp OUTEEE
INCH jmp INEEE
;
; PRINT DATA POINTED TO BY X REG
PDATA2 bsr OUTCH
inx
PDATA1 lda 0,x
cmpa #4
bne PDATA2
rts ; STOP ON HEX 04
;
C1 jmp SWTCTL
;
; MEMORY EXAMINE AND CHANGE
CHANGE bsr BADDR
CHA51 ldx #MCL
bsr PDATA1 ; C/R L/F
ldx #XHI
bsr OUT4HS ; PRINT ADDRESS
ldx XHI
bsr OUT2HS ; PRINT OLD DATA
bsr OUTS ; OUTPUT SPACE
ANOTH bsr INCH ; INPUT CHAR
cmpa #$20
beq ANOTH
cmpa #$D
beq C1
cmpa #'^' ; UP ARROW?
bra AL3 ; BRANCH FOR ADJUSTMENT
nop
;
; INPUT HEX CHARACTER
INHEX bsr INCH
INHEX1 suba #$30
bmi C3
cmpa #$9
ble IN1HG
cmpa #$11
bmi C3 ; NOT HEX
cmpa #$16
bgt C3 ; NOT HEX
suba #7
IN1HG rts
;
OUT2H lda 0,x ; OUTPUT 2 HEX CHAR
OUT2HA bsr OUTHL ; OUT LEFT HEX CHAR
lda 0,x
inx
bra OUTHR ; OUTPUT RIGHT HEX CHAR
;
OUT4HS bsr OUT2H ; OUTPUT 4 HEX CHAR + SPACE
OUT2HS bsr OUT2H ; OUTPUT 2 HEX CHAR + SPACE
;
OUTS lda #$20 ; SPACE
bra OUTCH ; (BSR & TRS)
;
; ENTER POWER ON SEQUENCE
START lds #STACK
bra AL1 ; BRANCH FOR ADDRESS COMPATIBIL
;
;********************************************
; PART OF MEMORY EXAMINE AND CHANGE
AL3 bne SK1
dex
dex
stx XHI
bra CHA51
SK1 stx XHI
bra AL4
;
EOE3 bra CONTRL ; BRANCH FOR MIKBUG EQUIV. CONT
;
AL4 cmpa #$30
bcs CHA51
cmpa #$46
bhi CHA51
bsr INHEX1
jsr BYTE1
dex
sta 0,x ; CHANGE MEMORY
cmpa 0,x
beq CHA51 ; DID CHANGE
jmp LOAD19 ; DIDN'T CHANGE
C3 lds SP
bra SWTCTL
;**************************************************
;
; CONTINUE POWER UP SEQUENCE
AL1 sts SP ; INIT TARGET STACK PTR.
lda #$FF
jsr SWISET
; CONFIGURE FOR PIA AND SEE IF OK
ldx #CTLPOR
jsr PIAINI ; INIT PIA
lda 0,x
cmpa 2,x
bra AL2
;
bra PRINT ; BRA FOR BILOAD
;
AL2 bne CONTRL
;
; INITIALIZE AS ACIA
lda #3 ; ACIA MASTER RESET
sta 0,x
lda #$11
sta 0,x
bra CONTRL
;
; ENTER FROM SOFTWARE INTERRUPT
SF0 nop
SFE1 sts SP ; SAVE TARGETS STACK POINTER
; DECREMENT P COUNTER
tsx
tst 6,x
bne *+4
dec 5,x
dec 6,x
; PRINT CONTENTS OF STACK.
PRINT ldx #MCL
jsr PDATA1
ldx SP
inx
bsr OUT2HS ; COND CODES
bsr OUT2HS ; ACC B
bsr OUT2HS ; ACC A
jmp PATCH1
nop
; BSR OUT4HS IXR
; BSR OUT4HS PGM COUNTER
PATCH2 ldx #SP
jsr OUT4HS ; STACK POINTER
SWTCTL ldx SWIJMP
cpx #SF0
beq CONTR1
;
CONTRL lds #STACK ; SET CONTRL STACK POINTER
ldx #CTLPOR ; RESET TO CONTROL PORT
stx PORADD
clr PORECH ; TURN ECHO ON
bsr SAVGET ; GET PORT # AND TYPE
beq POF1
jsr PIAECH ; SET PIA ECHO ON IF MP-C INTER
POF1 jsr PNCHOF ; TURN PUNCH OFF
jsr RDOFF ; TURN READER OFF
CONTR1 ldx #MCLOFF
jsr PDATA1 ; PRINT DATA STRING
bsr INEEE ; READ COMMAND CHARACTER
;
; COMMAND LOOKUP ROUTINE
LOOK ldx #TABLE
OVER cmpa 0,x
bne SK3
jsr OUTS ; SKIP SPACE
ldx 1,x
jmp 0,x
SK3 inx
inx
inx
cpx #TABEND+3
bne OVER
SWTL1 bra SWTCTL
;
; SOFTWARE INTERRUPT ENTRY POINT
SFE ldx SWIJMP ; JUMP TO VECTORED SOFTWARE INT
jmp 0,x
;
S9 fcb 'S9',4 ; END OF TAPE
;
;***************************************************
MTAPE1 fcb $D,$A,$15,0,0,0,'S1',4 ; PUNCH FORMAT
;
MCLOFF fcb $13 ; READER OFF
MCL fcb $D,$A,$15,0,0,0,'$',4
;
EIA5 bra BILD ; BINARY LOADER INPUT
;***************************************************
;
;
; NMI SEQUENCE
NMIV ldx NMI ; GET NMI VECTOR
jmp 0,x
;
INEEE bra INEEE1
;
; BYTE SEARCH ROUTINE
SEARCH jsr BADDR ; GET TOP ADDRESS
stx ENDA
jsr BADDR ; GET BOTTOM ADDRESS
jsr BYTE ; GET BYTE TO SEARCH FOR
tab
OVE lda 0,x
stx XHI
cba
beq PNT
bra INCR1
PNT ldx #MCL
jsr PDATA1
ldx #XHI
bra SKP0
;***************************************************
;
; GO TO USER PROGRAM ROUTINE
GOTO rti
OUTEEE bra OUTEE1
;
;
;
; SAVE IXR AND LOAD IXR WITH CORRECT
; PORT NUMBER AND TEST FOR TYPE
SAVGET stx XTEMP ; STORE INDEX REGISTER
GETPT1 ldx PORADD
ISACIA pshb
ldb 1,x
cmpb 3,x
pulb
rts
;***************************************************
;
; CONTINUATION OF SEARCH ROUTINE
SKP0 jsr OUT4HS
ldx XHI
INCR1 cpx ENDA
beq SWTL1
inx
bra OVE
;
INEEE1 bsr INCH8 ; INPUT 8 BIT CHARACTER
anda #%01111111 ; GET RID OF PARITY BIT
rts
;
BILD ins ; FIX UP STACK WHEN USING
ins ; BINARY LOADER ON SWTPC TAPES
ins
;
; INPUT ONE CHAR INTO ACC B
INCH8 pshb ; SAVE ACC B
bsr SAVGET ; SAVE IXR, GET PORT# AND TYPE
bne IN1 ; INPUT FROM PIA IF NOT
lda #$15 ; RECONFIG FOR 8 BIT, 1 SB
sta 0,x
ACIAIN lda 0,x
asra
bcc ACIAIN ; NOT READY
lda 1,x ; LOAD CHAR
ldb PORECH
beq ACIOUT ; ECHO
bra RES ; DON'T ECHO
;
; OUTPUT ONE CHARACTER
OUTEE1 pshb ; SAVE ACC B
bsr SAVGET
bne IOUT
;
ACIOUT ldb #$11
stb 0,x
ACIOU1 ldb 0,x
asrb
asrb
bcc ACIOU1 ; ACIA NOT READY
sta 1,x ; OUTPUT CHARACTER
RES pulb ; RESTORE ACC B
ldx XTEMP
rts
;
; PIA INPUT ROUTINE
IN1 lda 0,x ; LOOK FOR START BIT
bmi IN1
bsr DDL ; DELAY HALF BIT TIME
ldb #4 ; SET DEL FOR FULL BIT TIME
stb 2,x
aslb ; SET UP CNTR WITH 8
IN3 bsr DEL ; WAIT ONE CHAR TIME
sec
rol 0,x
rora
decb
bne IN3
bsr DEL ; WAIT FOR STOP BIT
ldb PORECH ; IS ECHO DESIRED?
beq IOUT2 ; ECHO
bra RES ; RESTORE IXR,ACCB
; PIA OUTPUT ROUTINE
IOUT bsr DDL1 ; DELAY ONE HALF BIT TIME
ldb #$A ; SET UP COUNTER
dec 0,x ; SET START BIT
bsr DE ; START TIMER
OUT1 bsr DEL ; DELAY ONE BIT TIME
sta 0,x ; PUT OUT ONE DATA BIT
sec
rora ; SHIFT IN NEXT BIT
decb ; DECREMENT COUNTER
bne OUT1 ; TEST FOR 0
IOUT2 ldb 2,x ; TEST FOR STOP BITS
aslb ; SHIFT BIT TO SIGN
bpl RES ; BRA FOR 1 STOP BIT
bsr DEL ; DELAY FOR STOP BITS
bra RES
DEL tst 2,x ; IS TIME UP
bpl DEL
DE inc 2,x ; RESET TIMER
dec 2,x
rts
;
DDL clr 2,x ; HALF BIT DELAY
DDL1 bsr DE
bra DEL
;
;
; OPTIONAL PORT ROUTINE
OPTL bsr INEEE1
tab
clr PORADD+1 ; SET I/O ADDRESS FOR $8000
ldx PORADD
bsr PIAINI ; INITIALIZE PIA
bsr PIAECH ; SET ECHO
ldx #TABLE1 ; P, L OR E
tba
jmp OVER ; LOOK AT TABLE FOR E, L OR P
;
PIAECH lda #$34 ; SET DDR
sta 3,x
sta 2,x
NOOPT rts
;
; PIA INITIALIZATION ROUTINE
PIAINI inc 0,x ; SET DDR
lda #$7
sta 1,x
inc 0,x
sta 2,x
rts
;
; MINIFLOPPY DISK BOOT
DISK clr $8014
bsr DELAY
ldb #$0B
bsr RETT2
LOOP1 ldb 4,x
bitb #1
bne LOOP1
clr 6,x
bsr RETURN
ldb #$9C
bsr RETT2
ldx #$2400
LOOP2 bitb #2
beq LOOP3
lda $801B
sta 0,x
inx
LOOP3 ldb $8018
bitb #1
bne LOOP2
jmp $2400
RETT2 stb 4,x
RETURN bsr RETT1
RETT1 rts
;
; GENERAL PURPOSE DELAY LOOP
DELAY ldx #$FFFF
DELAY1 dex
cpx #$8014 ; STOP AT 8014
DUM bne DELAY1
rts
;
;
; CLRAR SCREEN FOR CT-1024 TYPE TERMINALS
CLEAR ldx #CURSOR
jsr PDATA1
bsr DELAY1 ; DELAY
RDOFF1 bsr RDOFF
bra C4
;
; BREAKPOINT ENTERING ROUTINE
BREAK ldx #SF0
cpx SWIJMP ; BREAKPOINTS ALREADY IN USE?
beq INUSE
inx
BREAK0 bsr STO1
jsr BADDR
stx BKPT
lda 0,x
sta BKLST
lda #$3F
sta 0,x
ldx #SF0
bsr STO1
jmp CONTR1
INUSE ldx BKPT
lda BKLST
sta 0,x
ldx #SFE1
bra BREAK0
;
SWISET sta STACK+1 ; FIX POWER UP INTERRUPT
ldx SWIJMP
cpx #SF0
beq STORTN
STO ldx #SFE1
STO1 stx SWIJMP
STORTN rts
;
PUNCH1 bsr PUNCH
bra POFC4
;
; FORMAT END OF TAPE WITH PGM. CTR. AND S9
PNCHS9 ldx #$A049
stx ENDA
dex
bsr PUNCH2
ldx #S9
PDAT jsr PDATA1
POFC4 bsr PNCHOF
bsr DELAY
C4 jmp CONTRL
;
RDON com PORECH ; DISABLE ECHO FOR ACIA
lda #$11 ; RON CHAR.
ldb #$20 ; STROBE CHAR
bsr STROBE
jsr ISACIA ; CHECK TO SEE IF PIA
beq RTNN
lda #$3C ; DISABLE PIA ECHO IF PIA
sta 3,x
RTNN rts
;
RDOFF lda #$13 ; TURN READER OFF
ldb #$10
bra STROBE
;
PNCHON lda #$12
ldb #4
bra STROBE
;
PNCHOF lda #$14
ldb #$8
;
; PIA STROBING ROUTINE FOR PUNCH/READ ON/OFF
STROBE jsr OUTCH
jsr GETPT1
; beq RTN1
bra RTN1
;
; New code for stack dump
;
PATCH1 jsr OUT4HS ; IXR
jsr OUT4HS ; IYR
jsr OUT4HS ; PGM COUNTER
jmp PATCH2
; lda #2
; orb #1
; bsr STR2
; bsr STR1
; lda #2
; ldb #1
stb 0,x
bsr STR2
STR1 lda #6
STR2 sta 1,x
stb 0,x
RTN1 rts
; PUNCH FROM BEGINNING ADDRESS (BEGA) THRU
; ENDING ADDRESS (ENDA)
PUNCH ldx BEGA
PUNCH2 stx TW
bsr PNCHON
PUN11 lda ENDA+1
suba TW+1
ldb ENDA
sbcb TW
bne PUN22
cmpa #16
bcs PUN23
PUN22 lda #15
PUN23 adda #4
sta BYTECT
suba #3
sta TEMP
; PUNCH C/R L/F NULLS S1
ldx #MTAPE1
jsr PDATA1
clrb
; PUNCH FRAME COUNT
ldx #BYTECT
bsr PUNT2 ; PUNCH 2 HEX CHARACTERS
; PUNCH ADDRESS
ldx #TW
bsr PUNT2
bsr PUNT2
; PUNCH DATA
ldx TW
PUN32 bsr PUNT2 ; PUNCH ONE BYTE
dec TEMP
bne PUN32
stx TW
comb
pshb
tsx
bsr PUNT2 ; PUNCH CHECKSUM
pulb ; RESTORE STACK
ldx TW
dex
cpx ENDA
bne PUN11
RTN5 rts
; PUNCH 2 HEX CHAR, UPDATE CHECKSUM
PUNT2 addb 0,x
jmp OUT2H ; OUTPUT 2 HEX CHAR AND RTS
; COMMAND TABLE
TABLE fcb 'G' ; GOTO
fdb GOTO
fcb 'Z' ; GOTO PROM
fdb PROM
fcb 'M' ; MEMORY EXAM AND CHANGE
fdb CHANGE
fcb 'F' ; BYTE SEARCH
fdb SEARCH
fcb 'R' ; REGISTER DUMP
fdb PRINT
fcb 'J' ; JUMP
fdb JUMP
fcb 'C' ; CLEAR SCREEN
fdb CLEAR
fcb 'D' ; DISK BOOT
fdb DISK
fcb 'B' ; BREAKPOINT
fdb BREAK
fcb 'O' ; OPTIONAL PORT
fdb OPTL
TABLE1 fcb 'P' ; ASCII PUNCH
fdb PUNCH1
fcb 'L' ; ASCII LOAD
fdb LOAD
TABEND fcb 'E' ; END OF TAPE
fdb PNCHS9
#VECTORS $E3F8
fdb IRQV ; IRQ VECTOR
fdb SFE ; SOFTWARE INTERRUPT
fdb NMIV ; NMI VECTOR
fdb START ; RESTART VECTOR
#VECTORS $A048
fdb START
end