-
Notifications
You must be signed in to change notification settings - Fork 4
/
Copy pathancilla_skull_woods_fire.asm
295 lines (170 loc) · 6.41 KB
/
ancilla_skull_woods_fire.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
; ==============================================================================
; $46EDE-$46F99 DATA
pool Ancilla_SkullWoodsFire:
{
.flame_y_offsets_low
db 0, 0, 0, -3
.flame_y_offsets_high
db 0, 0, 0, -1
.flame_chr
db $8E, $A0, $A2, $A4
.flame_properties
db $02, $02, $02, $00
.blast_chr
db $86, $86, $86, $FF, $FF, $FF
db $86, $86, $86, $86, $86, $86
db $8A, $8A, $8A, $8A, $8A, $8A
db $9B, $9B, $9B, $9B, $9B, $9B
.blast_properties
db $00, $00, $00, $00, $00, $00
db $00, $00, $00, $00, $00, $00
db $00, $00, $00, $00, $00, $00
db $80, $40, $40, $80, $40, $00
.blast_oam_sizes
db $02, $02, $02, $02, $01, $01
db $02, $02, $02, $02, $02, $02
db $02, $02, $02, $02, $02, $02
db $00, $00, $00, $00, $00, $00
.blast_y_offsets
dw -31, -24, -22, -1, -1, -1
dw -37, -32, -32, -23, -16, -14
dw -37, -32, -32, -23, -16, -14
dw -35, -29, -28, -20, -13, -11
.blast_x_offsets
dw -13, -21, -10, -1, -1, -1
dw -16, -27, -4, -16, -6, -25
dw -16, -27, -4, -16, -6, -25
dw -13, -5, -27, -11, -22, -3
.blast_data_offsets
db 0, 6, 12, 18
}
; ==============================================================================
; *$46F9A-$47168 JUMP LOCATION
Ancilla_SkullWoodsFire:
{
LDA $7F0010 : BEQ .blast_inactive
LDA $0C5E, X : CMP.b #$04 : BEQ .blast_inactive
DEC $03B1, X : BPL .blast_state_delay
LDA.b #$05 : STA $03B1, X
INC $0C5E, X
.blast_state_delay
.blast_inactive
LDX.b #$03
LDY.b #$00
.execute_next_flame
LDA $7F0008, X : DEC A : STA $7F0008, X
BMI .reset_flame_animation_index
.flame_permanently_inactive
.dont_reset_flame_control_index
BRL .draw_flames_logic
.reset_flame_animation_index
LDA.b #$05 : STA $7F0008, X
LDA $7F0000, X : CMP.b #$80 : BEQ .flame_permanently_inactive
INC A : STA $7F0000, X : BEQ .flame_control_state_reset
CMP.b #$04 : BNE .dont_reset_flame_control_index
LDA.b #$00 : STA $7F0000, X
.flame_control_state_reset
REP #$20
LDA $7F0018 : SUB.w #$0008 : STA $7F0018
CMP.w #$00C8 : BCS .dont_play_thud_sfx
LDA.w #$0098 : SUB $E2 : STA $00
SEP #$20
LDA $7F0010 : CMP.b #$01 : BEQ .dont_play_thud_sfx
; Activate the blast component of this object.
LDA.b #$01 : STA $7F0010
LDA $00 : JSR Ancilla_SetSfxPan_NearEntity : ORA.b #$0C : STA $012E
.dont_play_thud_sfx
REP #$20
LDA $7F0018 : CMP.w #$00A8 : BCS .dont_permadeativate_flame
LDA $7F0000, X : AND.w #$FF00 : ORA.w #$0080 : STA $7F0000, X
.dont_permadeativate_flame
PHX : TXA : ASL A : TAX
LDA $7F001A : STA $7F0030, X
LDA $7F0018 : STA $7F0020, X
PLX
SEP #$20
LDA $012E : BNE .sfx2_already_set
LDA $7F001A : SUB $E2
JSR Ancilla_SetSfxPan_NearEntity : ORA.b #$2A : STA $012E
.sfx2_already_set
.draw_flames_logic
SEP #$20
PHX
LDA $7F0000, X : BPL .active_flame
BRL .inactive_flame
.active_flame
PHY
TAY
LDA .flame_y_offsets_low, Y : STA $04
LDA .flame_y_offsets_high, Y : STA $05
LDA .flame_chr, Y : STA $06
LDA .flame_properties, Y : STA $07
TXA : ASL A : TAX
REP #$20
LDA $7F0020, X : SUB $E8 : ADD $04 : STA $00
LDA $7F0030, X : SUB $E2 : STA $02
ADD.w #$0008 : STA $08
SEP #$20
PLY
JSR Ancilla_SetOam_XY
LDA $06 : STA ($90), Y : INY
LDA.b #$32 : STA ($90), Y : INY
PHY
TYA : SUB.b #$04 : LSR #2 : TAY
LDA $07 : STA ($92), Y
PLY
CMP.b #$02 : BEQ .large_oam_entry
REP #$20
LDA $08 : STA $02
SEP #$20
JSR Ancilla_SetOam_XY
LDA $06 : INC A : STA ($90), Y
INY
LDA.b #$32 : STA ($90), Y
INY : PHY
TYA : SUB.b #$04 : LSR #2 : TAY
LDA $07 : STA ($92), Y
PLY
.large_oam_entry
.inactive_flame
PLX : DEX : BMI .done_executing_flames
BRL .execute_next_flame
.done_executing_flames
LDX.b #$03
.find_active_flame_loop
LDA $7F0000, X : BPL .flames_not_all_inactive
DEX : BPL .find_active_flame_loop
LDX $0FA0
STZ $0C4A, X
RTS
.flames_not_all_inactive
LDX $0FA0
LDA $7F0010 : BEQ .blast_logic_inactive
LDA $0C5E, X : CMP.b #$04 : BEQ .blast_logic_inactive
TAX
LDA .blast_data_offsets, X : TAX
STZ $08
.next_blast_oam_entry
LDA .blast_chr, X : CMP.b #$FF : BEQ .skip_blast_oam_entry
PHX
TXA : ASL A : TAX
REP #$20
LDA.w #$00C8 : SUB $E8 : ADD .blast_y_offsets, X : STA $00
LDA.w #$00A8 : SUB $E2 : ADD .blast_x_offsets, X : STA $02
SEP #$20
PLX
JSR Ancilla_SetOam_XY
LDA .blast_chr, X : STA ($90), Y : INY
LDA .blast_properties, X : ORA.b #$30 : ORA.b #$02 : STA ($90), Y
INY : PHY
TYA : SUB.b #$04 : LSR #2 : TAY
LDA .blast_oam_sizes, X : STA ($92), Y
PLY
.skip_blast_oam_entry
INX
INC $08
LDA $08 : CMP.b #$06 : BNE .next_blast_oam_entry
.blast_logic_inactive
BRL Ancilla_RestoreIndex
}
; ==============================================================================