pandoc-bin: re-add

archlinuxcn/pandoc-bin/PKGBUILD

@@ -0,0 +1,40 @@
+pkgname=pandoc-bin
+pkgver=3.6.2
+pkgrel=1
+pkgdesc="Conversion between documentation formats"
+url="https://pandoc.org"
+license=("GPL-2.0-or-later")
+arch=('x86_64' 'aarch64')
+conflicts=("pandoc-cli")
+provides=("pandoc=$pkgver" "pandoc-cli=$pkgver")
+optdepends=(
+  'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+  'texlive-context: for pdf output using context engine'
+  'groff: for pdf output using pdfroff engine'
+  'python-weasyprint: for pdf output using weasyprint engine'
+  'typst: for pdf output using typst engine'
+  'tectonic: for pdf output using tectonic engine'
+  'texlive-fontsrecommended: for pdf output using latex or xelatex engines'
+  'texlive-latex: for pdf output using pdflatex engine'
+  'texlive-xetex: for pdf output using xelatex engine'
+)
+
+# The binary release doesn't have the datafiles, so we need to yoink those out of the source tarball, too.
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/pandoc/archive/${pkgver}.tar.gz")
+source_x86_64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-amd64.tar.gz")
+source_aarch64=("https://github.com/jgm/pandoc/releases/download/${pkgver}/pandoc-${pkgver}-linux-arm64.tar.gz")
+
+sha256sums=('068a0fd99dcd34e99aec0cd039d8d7cdb6b16bf20e338549cc562717c8bcb21f')
+sha256sums_x86_64=('f11b3f21549f23e3d5b99dfacb96560c04c2f76027edb787c4d6551849acf54a')
+sha256sums_aarch64=('eeaf4e6449794b7819de52c1ac6c55a1d4b49faa6edd3243d93013469f70ae00')
+
+package() {
+  cd "${srcdir}/pandoc-${pkgver}"
+
+  mkdir -p "${pkgdir}/usr/share/pandoc"
+  cp -R bin share "${pkgdir}/usr"
+  cp -R data citeproc "${pkgdir}/usr/share/pandoc/"
+  cp COPYRIGHT MANUAL.txt "${pkgdir}/usr/share/pandoc/"
+}
+
+# vim: set ts=2 sw=2 et

archlinuxcn/pandoc-bin/lilac.yaml

@@ -0,0 +1,11 @@
+maintainers:
+  - github: Xeonacid
+    email: xeonacid@archlinuxcn.org
+
+pre_build_script: aur_pre_build(maintainers=['a821'])
+
+post_build: aur_post_build
+
+update_on:
+  - source: aur
+    aur: pandoc-bin